monitor("lezione17-03-21.txt","io");

//////////////////////////////////////////////////////////////////////
//  Inviluppo di una famiglia di curve, esempio [CLO, pp. 147-152]  //
//////////////////////////////////////////////////////////////////////

ring R = 0, (t,x,y), lp; //ordine lessicografico t > x > y
option(redSB);
poly F = (x - t)^2 + (y - t^2)^2 - 4; 

// F definisce una famiglia di circonferenze coi centri lungo una parabola.

ideal I = F, diff(F,t);
ideal g = std(I);

// inviluppo della famiglia F = {(x,y)| esiste un numero reale t con (x,y,t) in V(I)}

g;

// L'inviluppo e' contenuto nella curva  V(g[1]).
// Poiche' il coefficiente principale di t in g[5] e' costante = 135,
// segue dal teorema di estensione che ogni soluzione (x,y) si estende
// a una soluzione (x,y,t) del sistema g (con t un numero complesso!)
// e al massimo a due soluzioni (il grado di g[5] in t e' due).

// Utilizzando g[2]=A2(x,y)*t+B2(x,y), g[3]=A3(x,y)*t+B3(x,y), g[4]=A4(x,y)*t+B4(x,y),
// si trova che t = -B2/A2 = -B3/A3 = -B4/A4  e' reale.
// Calcoliamo le A:

poly A2 = diff(g[2],t);
poly A3 = diff(g[3],t);
poly A4 = diff(g[4],t);
ideal A = A2, A3, A4; 

// V(A) = luogo nel piano x,y, dove le A si annullano simultaneamente.
// Vedremo che V(A) = luogo singolare di V(g[1]) = V(g[1],diff(g[1],x),diff(g[1],y)).

ideal sA = std(A);

// Infatti, g[1], diff(g[1],x) e diff(g[1],y) sono in A:

reduce(g[1],sA);
reduce(diff(g[1],x),sA);
reduce(diff(g[1],y),sA);

// D'altra parte, A2^2, A3^2, A4^2 sono nell'ideale generato 
// da g[1],diff(g[1],x),diff(g[1],y):

ideal G = g[1],diff(g[1],x),diff(g[1],y);
ideal sG = std(G);
reduce(A2^2,sG);
reduce(A3^2,sG);
reduce(A4^2,sG);

monitor("");
quit;