% Authors: R/"udiger Achilles and Davide Aliffi
% achilles@dm.unibo.it, aliffi@dm.unibo.it

COMMENT
 
This is an example session demonstrating and testing the facilities
offered by the module SEGRE, an extension of the REDUCE package CALI.
 
END COMMENT;
  
comment
 
        ##################################################
        ###                                            ###
        ###         Joins, secant varieties,           ###
        ###   relative tangent cones, limits of joins  ###
        ###                                            ###
        ##################################################
 end comment;
 
% Example 1. Relative tangent cone.

% [T. Krasi{\'n}ski: The join of algebraic curves. Preprint University
% of Lodz, 2000], Example 3.8, or T. Krasi{\'n}ski: Relative tangent
% cone to analytic curves. Preprint University of Lodz, 2000],
% Example 1.
% Given A:={(t^2,t^3,0): t \in C} and B:={(t^2,0,t^3): t \in C},
% we calculate the ideal of the relative tangent cone C_0(A,B):

setring({x,y,z},{},lex);
a:={y**2-x**3,z};
b:={z**2-x**3,y};
rtc:=ljoin(a,b);

% If we want only the underlying analytic set of the relative
% tangent cone of A and B at O, then we need to compute the radical:

setideal(rtc,rtc)$
radical rtc;

% Example 2. Secant variety.

% This example has been taken from
% [A. Simis and B. Ulrich: On the ideal of an embedded join.
% J. Algebra 226 (2000), 1-14], Example 2.4
% or [A. Simis: Algebraic aspects of tangent cones. In: Matem{\'a}tica
% Contempor{\'a)nea, Proceedings of the XII Escola de {\'A}lgebra,
% D. Avritzer and M. Spira, Eds., Diamantina, Brazil, 1994]
% Example 5.8.

% Let us consider the projective variety X in P^5 defined by the
% following ideal p:

setring(rest vars 6,{},lex);
setideal(p,
{x1*x2-x2*x5+x3*x5-x5*x6,x1*x3+x1*x4+x1*x6+x4*x5,x1*x6+x3*x5,
x2*x3+x2*x6-x3*x6+x6**2,x2*x4+x3*x6,x3**2+x3*x4+x3*x6-x4*x6});
isprime p;
    
% Let us compute the secant variety Sec(X) = Join(X,X).

ljoin(p,p);

% The result means that Sec(X) = P^5.
% The initial ideal of p with respect to the lexicographic order
% with x1 > x2 > x4 > x5 > x3 > x6 is:

setideal(inp,{x1*x2,x1*x4,x1*x6,x2*x3,x2*x4,x3*x4});

% It defines an arithmetically Cohen-Macaulay surface whose secant
% variety is non-equidimensional of dimension 4.

setideal(sec,ljoin(inp,inp));
primarydecomposition sec;
adeg sec;

% Example 3. Secant variety of the 
%                        Segre embedding X = P^2 x P^2 -> P^8;
% see e.g., [H. Flenner, L. O'Carroll, W. Vogel: Joins and 
% intersections. Springer-Verlag Berlin-Heidelberg, 1999], p. 26-27.

% The ideal id of the Segre embedding is generated by the 2 x 2-minors
% of a generic 3 x 3-matrix m.
 
setring(vars 8,{},lex);   
m:=mat((x0,x1,x2),(x3,x4,x5),(x6,x7,x8));
id:=ideal_of_minors(m,2);
sec:=ljoin(id,id);

% The result shows us that the secant variety is a hypersurface
% of degree 3. In fact, its equation is the determinant of m.

det m;

% Example 4. Secant variety of the Veronesion surface v in P^5;
% see op. cit.

v:=veronese(2,2);
secv:=ljoin(v,v);

% The equation of the secant variety is the determinant of a 
% symmetric matrix s.

s:=mat((x0,x1,x2),(x1,x3,x4),(x2,x4,x5));
det s;
;end;