Polinomi di Chebyshev

Clear["Global`"]

Pafnuti  L'vovich Chebyshev (1821-1894)

Definiamo il polinomio di Chebyshev di grado n:

T[n_, x_] :=  
      Sum[Binomial[n, 2  h] (-1)^h x^(n - 2  h) (1 - x^2)^
            h, {h, 0, n/2}]

Table[T[n, x], {n, 1, 4}]

Plot[
        Evaluate[%],  {x, -1, 1}, 
AspectRatio -> 
          Automatic];

Per x ∈ [–1,1] il polinomio T[n, x] coincide con la funzione cos[n arccos(x)]:

Plot[
        Evaluate[Table[Cos[n ArcCos[x]], {n, 1, 4}]],  {x, -1, 
          1},  
AspectRatio -> 
          Automatic];

Definizione ricorsiva dei polinomi di Chebyshev:

Trc[1, x_]  :=  x

Trc[2, x_]  :=  2  x^2  -  1

Trc[n_, x_] :=  
      2  x Trc[n - 1, x]  -  Trc[n - 2, x] // Expand

Trc[3, x]

Trc[4, x]

Le funzioni cos nt, n naturale, sono ortogonali sull'intervallo [ 0, π] rispetto alla norma di (L^(2 )):

Integrate[Cos[n*t] Cos[m*t], {t, 0, π}]

Simplify[%, (n ∈ Integers) ∧ (m ∈ 
            Integers) ∧ (n  ≠  m)]

I quadrati delle norme valgono:

Integrate[Cos[n*t]^2, {t, 0, π}]

Simplify[%, (n ∈ Integers) ∧ (n  ≠  
            0)]

mentre, evidentemente, per n = 0 si ha come quadrato della norma π.

Partiamo dall'integrale (nullo):

HoldForm[Integrate[Cos[n*t] Cos[m*t],  {t, 0, π}]]

Operiamo il cambiamento di variabile t = arccos[x].

Plot[ArcCos[x],  {x, -1, 1},  
        AspectRatio -> Automatic];

Otteniamo l'integrale

HoldForm[-Integrate[
            T[n, x] T[m, x]/Sqrt[1 - x^2],  {x, 
              1, -1}]  =  
Integrate[
          T[n, x] T[m, x]/Sqrt[1 - x^2],  {x, -1, 1}]]

Abbiamo dunque una relazione di ortogonalità dei polinomi di Chebyshev rispetto al peso (1/(Sqrt[1 - (x^2)])).

Alcune verifiche:

Integrate[T[2, x] T[3, x]/Sqrt[1 - x^2],  {x, -1, 1}]

Integrate[T[2, x] T[4, x]/Sqrt[1 - x^2],  {x, -1, 1}]

Integrate[T[2, x]^2/Sqrt[1 - x^2], {x, -1, 1}]

Integrate[T[3, x]^2/Sqrt[1 - x^2], {x, -1, 1}]